4D Doc Center : Command name

4D v13.4

Command name


Command name ( comando ) -> Resultado

Parámetro	Tipo	Descripción
comando	Entero largo	Número del comando
Resultado	Cadena	Nombre del comando traducido

Descripción

El comando Command name devuelve el nombre literal del comando cuyo número se pasa en comando.

4D integra una traducción dinámica de palabras claves, constantes y nombres de comandos utilizados en sus métodos. Por ejemplo, si utiliza la versión inglesa de 4D, usted escribe:

 DEFAULT TABLE([MiTabla])

 ALL RECORDS([MiTabla])

Este mismo código, si se abre con la versión francesa de 4D, se traducirá automáticamente:

 TABLE PAR DEFAUT([MiTabla])

 TOUT SELECTIONNER([MiTabla])

Sin embargo, 4D también incluye una característica única, el comando EXECUTE FORMULA, el cual le permite construir código improvisadamente y luego ejecutarlo, aunque la base esté compilada.

El código de ejemplo, escrito con EXECUTE FORMULA en inglés, se verá así:

 EXECUTE FORMULA("DEFAULT TABLE([MiTabla])")

 EXECUTE FORMULA("ALL RECORDS([MiTabla])")

El mismo código, abierto con la versión francesa de 4D, se traduce automáticamente:

 EXECUTER FORMULE("DEFAULT TABLE([MiTabla])")

 EXECUTER FORMULE("ALL RECORDS([MiTabla])")

4D traduce automáticamente EXECUTE FORMULA (inglés) a EXECUTER FORMULE (francés), pero no puede traducir las instrucciones pasadas al comando.

Si utiliza el comando EXECUTE FORMULA en su aplicación, puede utilizar Command name para eliminar los problemas de traducción asociados a este tipo de instrucciones, y así hacer instrucciones independientes del idioma. El código de ejemplo se convierte en:

 EXECUTE FORMULA(Command name(46)+"([MiTabla])")

 EXECUTE FORMULA(Command name(47)+"([MiTabla])")

Con una versión francesa de 4D, este código será:

 EXECUTER FORMULE(Nom commande(46)+"([MiTabla])")

 EXECUTER FORMULE(Nom commande(47)+"([MiTabla])")

Nota: el número de cada comando está en el área de Propiedades de la página de documentación del comando.

Ejemplo 1

Para todas las tablas de su base de datos, usted tiene un formulario llamado “FORMULARIO DE ENTRADA” utilizado para la entrada de datos en cada tabla. Si quiere añadir un método de proyecto genérico que va a designar este formulario como el formulario de entrada actual para la tabla cuyo puntero o nombre se pasó, usted escribe:

  ` Método de proyecto FORMULARIO ENTRADA ESTANDAR

  ` FORMULARIO ENTRADA ESTANDAR ( Puntero {; Cadena })

  ` FORMULARIO ENTRADA ESTANDAR ( ->Tabla {; NomTabla })

 C_POINTER($1)

 C_STRING(31;$2)

 

 [

 If(Count parameters>=2)

    EXECUTE FORMULA(Command name(55)+"(["+$2+"];"+Char(Double quote)+"FORMULARIO DE ENTRADA"+Char(Double quote)+")")

 Else

    If(Count parameters>=1)

       FORM SET INPUT($1->;"FORMULARIO DE ENTRADA")

    End if

 End if

Una vez añadido este método de proyecto a su base, usted escribe:

 FORMULARIO ENTRADA ESTANDAR(->[Empleados])

 FORMULARIO ENTRADA ESTANDAR("Empleados")

Nota: generalmente, es preferible utilizar punteros para escribir rutinas genéricas. Primero, el código se ejecutará compilado si la base está compilada. Luego, como en el ejemplo anterior, su código dejará de funcionar correctamente si renombra la tabla. Sin embargo, en algunos casos, la utilización de EXECUTE FORMULA resolverá el problema.

Ejemplo 2

En un formulario, usted quiere mostrar una lista desplegable que contenga los comandos estándar de generación de informes. En el método de objeto de esta lista desplegable, usted escribe:

 Case of

    :(Form event=On Before)

       ARRAY TEXT(asComando;4)

       asComando{1}:=Command name(1) ` Suma

       asComando{2}:=Command name(2) ` Promedio

       asComando{3}:=Command name(4) ` Min

       asComando{4}:=Command name(3) ` Max

  ` ...

 End case

En la versión inglesa de 4D, la lista desplegable contendrá: Sum, Average, Min, y Max. En la versión francesa, la lista desplegable contendrá: Somme, Moyenne, Min, y Max.